home *** CD-ROM | disk | FTP | other *** search
/ The Glitch Apple Disk Collection / 2014.glitch.apple.collection.zip / indexed / IFRSIM.DSK / DAYTONA NDB.bas < prev    next >
BASIC Source File  |  2014-09-09  |  4KB  |  108 lines
  1. 20 S = 100:S1 = 0:UP = 24579
  2. 30 ST = 24576:O1 = ST +56:O2 = ST +58:I1 = ST +60:I2 = ST +61:MA = ST +12:X1 = ST +26:Y1 = ST +28:AL = ST +87
  3. 40 SH = ST +09:PL = ST +06:LI = ST +15:XY = ST +18:DF = ST +39:CH = ST +93:WS = ST +42:WW = ST +43:WN = ST +44:WE = ST +45
  4. 60 XC = 141:YC = 71:XF = 141:YF = 71
  5. 70  TEXT : GOSUB 600
  6. 80 MT = 15:GAS = 0:MI = 0:SE = 0:S1 = 0
  7. 81  REM 
  8. 82  REM   SET UP WIND DRIFT
  9. 83  REM 
  10. 90  POKE WN,0: POKE WE,0: POKE WS,0: POKE WW,0
  11. 100 A% =  RND(1) *5:B% =  RND(1) *50
  12. 110  ON A% GOTO 120,130,140,150
  13. 120  POKE WN,B%: GOTO 160
  14. 130  POKE WE,B%: GOTO 160
  15. 140  POKE WS,B%: GOTO 160
  16. 150  POKE WW,B%: GOTO 160
  17. 160  CALL ST
  18. 165  HTAB 1: VTAB 23: PRINT "WIND ";A%;" AT ";B%;" KNOTS";
  19. 170  POKE O1,32: POKE O2,32: POKE I1,48: POKE I2,48
  20. 171  REM 
  21. 172  REM 
  22. 175  REM  OMNI MESSAGE AND
  23. 176  REM  STARTING X Y CORD
  24. 177  REM 
  25. 180  VTAB 22: HTAB 1: PRINT "OMNI IS ORMOND BEACH 190 DEGREES FROM"
  26. 190  POKE X1,145: POKE Y1,80
  27. 191  REM 
  28. 192  REM  STARTING ALTITUDE
  29. 193  REM 
  30. 200  POKE AL,16: POKE AL -3,32:MA% = 2
  31. 201  REM 
  32. 202  REM 
  33. 210  CALL UP
  34. 220 S1 = S1 +1: IF S1 >S  THEN 270
  35. 230  GOTO 210
  36. 240  REM  
  37. 250  REM    UPDATE THE CLOCK
  38. 260  REM  
  39. 270 S1 = 0:SE = SE +1: IF SE <60  THEN 280
  40. 271 SE = 0:MI = MI +1:GA = GA +1: IF GA = MT  THEN 550
  41. 272  GOTO 210
  42. 280  HTAB 1: VTAB 24: PRINT HO;":";MI;":";SE;"     ";
  43. 281  REM 
  44. 282  REM   DO ADF AND OMNI
  45. 283  REM 
  46. 290 X =  PEEK(X1):Y =  PEEK(Y1)
  47. 300 IX = XF -X:IY = YF -Y:DY = X -(178 -Y/2):DX = Y -(142 -X/2)
  48. 302  REM    DO THE ADF
  49. 303  REM 
  50. 310  IF IX = 0  THEN 330
  51. 320 IT = IY/IX
  52. 330 T1 =  ATN(IT)
  53. 340 T1% = 16 -10 *T1
  54. 350  IF X >XF  THEN PF% = (176 -T1%) - PEEK(CH)
  55. 360  IF X <XF  THEN PF% = (208 -T1%) - PEEK(CH)
  56. 370  IF PF% >64  THEN PF% = PF% -64: GOTO 370
  57. 380  POKE DF,PF%
  58. 381  REM 
  59. 382  REM   DO THE OMNI
  60. 383  REM 
  61. 390  IF DY < -5  THEN DY =  -6
  62. 400  IF DY >5  THEN DY = 6
  63. 410  IF DX < -5  THEN DX =  -6
  64. 420  IF DX >5  THEN DX = 6
  65. 450  POKE O1,32 +DX: POKE I1,48
  66. 460  POKE O2,32 -DY: POKE I2,48
  67. 461  REM 
  68. 462  REM   DO THE GLIDE SLOPE
  69. 463  REM 
  70. 470 SL = 178 -X:DI = SL - PEEK(AL) *2
  71. 471  VTAB 23: HTAB 20: PRINT SL;"  ";DI;"  ";
  72. 480  IF DI >5  THEN DI = 6
  73. 481  IF DI < -5  THEN DI =  -6
  74. 482  IF SL >40  THEN 540
  75. 483  IF SL < -10  THEN 540
  76. 484  POKE I2,48: POKE I1,48 +DI
  77. 540  IF  PEEK(AL) >MA%  THEN 210
  78. 545  REM 
  79. 546  REM   DO THE AIRPORT
  80. 547  REM 
  81. 550  HGR : HCOLOR= 3: CALL 24588
  82. 551  REM 
  83. 552  REM   FIRST THE AIRPORT
  84. 553  REM 
  85. 555  HPLOT 178,52: HPLOT  TO 190,45
  86. 556  HPLOT 187,55: HPLOT  TO 192,52
  87. 557  HPLOT 189,49: HPLOT  TO 184,43
  88. 580  REM 
  89. 582  REM   THEN THE NAV TRACK
  90. 583  REM 
  91. 584  HCOLOR= 2
  92. 585  FOR I = 50 TO 170:J = 142 -I/2: HPLOT I,J: NEXT 
  93. 587  FOR J = 5 TO 100:I = 178 -J/2: HPLOT I,J: NEXT 
  94. 590  HOME : VTAB 23: PRINT "HIT RETURN TO FLY THIS AGAIN": PRINT "ANY OTHER KEY FOR MENU": GET A$: IF  ASC(A$) = 13  THEN 70
  95. 595  PRINT  CHR$(4)
  96. 596  PRINT  CHR$(4);"RUN MENU"
  97. 599  END 
  98. 600  TEXT : HOME : PRINT "YOU ARE CLEARED";
  99. 601  PRINT " FOR DAYTONA BEACH"
  100. 602  PRINT : PRINT "REGIONAL (DAB) NDB APPROACH TO RWY 6L"
  101. 630  PRINT : PRINT "FLY DIRECT TOMOK NDB THEN MAKE"
  102. 640  PRINT : PRINT "PROCEDURE TURN OUTBOUND 245 DEGREES"
  103. 650  PRINT : PRINT "INBOUND 065 DEGREES.  OMNI IS SET TO"
  104. 660  PRINT : PRINT "ORMOND BEACH 190 RADIAL FROM"
  105. 670  PRINT : PRINT "MAINTAIN AT OR ABOVE 1600 TILL INBOUND"
  106. 680  PRINT : PRINT "PAST THE FINAL APPROACH FIX"
  107. 690  PRINT : PRINT "COPYRIGHT 1981 BY VERNON BROWN": PRINT "2110 N 2ND ST": PRINT "CABOT ARK 72023 (501) 843 2988": PRINT 
  108. 6000  PRINT : PRINT "HIT ANY KEY WHEN READY TO FLY": GET A$: HOME : RETURN